Purchased item on steam, but item won't download

[buzz456]

Look in your program files and see if the Steam folder is still there. Or better yet do a whole computer search for 'Railworks' and or 'Content' and see if either show up. If they do your stuff is still there even if right now you can't get Railworks to run.

[BoostedFridge]

Thanks for the quick reply!

It looks like I'm S.O.L. on this one; no Railworks folder. The game is downloading now, so I'll see how far back this sets me in 15 minutes.

To get my route back into the game, is it a matter of just dropping the folder for it back into the 'Content'/'Routes' folder?

[UPSD70ACe]

Yup always worked for me dropping the Route folder in Routes,Hope it works out bro ya bro good luck.

[Chacal]

Your Railworks folder was entirely erased?
Then yes.
You may try an undelete utility, though.

[BoostedFridge]

Well, lesson learned here. Backup your routes if you don't want to lost progress. Only 31 miles of track, and some terrain and scenery to redo...

[Chacal]

Yup. Especially since it is quick and easy to set-up a two-click backup.
Here's a trick. Use the following code in a .BAT file to take a quick snapshot of a route.
It will create a new folder with the date and time, every time you use it.
Put a shortcut to this BAT file on your desktop. Double-click on it and it's done.
Use many times a night when you are working on the route.
Delete a few older backups when you need disk space.

Code: Select all

@ECHO OFF
REM Backup of Railworks route in progress
REM This will copy files from the source folder to a new destination folder
REM The name of the destination folder is the current date and time

REM Change variables "Source" and "Destination" in the two lines below to suit your project
SET Source=I:\Steam\steamapps\common\railworks\Content\Routes\00000001-0000-0000-0000-000000000000
SET Destination=J:\railworks\MyRoute

REM Change variable "Files" for your file filter if needed
SET Files=*.*

REM We use current date and time for versioning
REM Note that the output of date and time is locale-dependent
REM You will have to adjust the parsing to fit the output of your DATE and TIME commands.
REM To do this, open a command window (Start / Run / cmd)
REM Type DATE. Whatever comes after "The current date is: " is your localized date format.
REM Type TIME. Whatever comes after "The current time is: " is your localized time format.
REM Then adjust the following SET lines to set variables correctly for year, month, etc.


rem Parse the date (e.g., 2013-01-01)
rem Example: the line below takes the first 4 characters of "2013-01-01" and puts them in "cur_year".
set cur_year=%date:~0,4%
set cur_mo=%date:~5,2%
set cur_da=%date:~8,2%

rem Parse the time (e.g., 16:20:08,69)
set cur_hh=%time:~0,2%
if %cur_hh% lss 10 (set cur_hh=0%time:~1,1%)
set cur_mm=%time:~3,2%
set cur_ss=%time:~6,2%
set cur_ms=%time:~9,2%

rem Set the timestamp format
set timestamp=backup%cur_year%%cur_mo%%cur_da%%cur_hh%h%cur_mm%
rem Example: backup2013010116h37

ECHO %timestamp%
CD %Destination%
MD %timestamp%
CD %timestamp%
XCOPY %Source%\%Files% /S
PAUSE

rem Clear environment variables
set cur_year=
set cur_mo=
set cur_da=
set cur_hh=
set cur_mm=
set cur_ss=
set cur_ms=
set timestamp=
Set Source=
Set Destination=
Set Files=


Note: I can't know your local DATE and TIME formats, but just follow the instructions and you should be OK.

[BoostedFridge]

Thats fantastic! Thanks Chacal!